1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
|
// Copyright 2018 The gVisor Authors.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
#include "funcdata.h"
#include "textflag.h"
// fxrstor loads floating point state.
//
// The code corresponds to:
//
// fxrstor64 (%rbx)
//
TEXT ·fxrstor(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), BX
MOVL $0xffffffff, AX
MOVL $0xffffffff, DX
BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0x0b;
RET
// xrstor loads floating point state.
//
// The code corresponds to:
//
// xrstor (%rdi)
//
TEXT ·xrstor(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), DI
MOVL $0xffffffff, AX
MOVL $0xffffffff, DX
BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0x2f;
RET
// fxsave saves floating point state.
//
// The code corresponds to:
//
// fxsave64 (%rbx)
//
TEXT ·fxsave(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), BX
MOVL $0xffffffff, AX
MOVL $0xffffffff, DX
BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0x03;
RET
// xsave saves floating point state.
//
// The code corresponds to:
//
// xsave (%rdi)
//
TEXT ·xsave(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), DI
MOVL $0xffffffff, AX
MOVL $0xffffffff, DX
BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0x27;
RET
// xsaveopt saves floating point state.
//
// The code corresponds to:
//
// xsaveopt (%rdi)
//
TEXT ·xsaveopt(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), DI
MOVL $0xffffffff, AX
MOVL $0xffffffff, DX
BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0x37;
RET
// writeFS writes to the FS base.
//
// This is written in assembly because it must be safe to call before the Go
// environment is set up. See comment on start().
//
// Preconditions: must be running in the lower address space, as it accesses
// global data.
TEXT ·writeFS(SB),NOSPLIT,$8-8
MOVQ addr+0(FP), AX
CMPB ·hasFSGSBASE(SB), $1
JNE msr
PUSHQ AX
CALL ·wrfsbase(SB)
POPQ AX
RET
msr:
PUSHQ AX
CALL ·wrfsmsr(SB)
POPQ AX
RET
// wrfsbase writes to the FS base.
//
// The code corresponds to:
//
// wrfsbase %rax
//
TEXT ·wrfsbase(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), AX
BYTE $0xf3; BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0xd0;
RET
// wrfsmsr writes to the FSBASE MSR.
//
// The code corresponds to:
//
// wrmsr (writes EDX:EAX to the MSR in ECX)
//
TEXT ·wrfsmsr(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), AX
MOVQ AX, DX
SHRQ $32, DX
MOVQ $0xc0000100, CX // MSR_FS_BASE
BYTE $0x0f; BYTE $0x30;
RET
// wrgsbase writes to the GS base.
//
// The code corresponds to:
//
// wrgsbase %rax
//
TEXT ·wrgsbase(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), AX
BYTE $0xf3; BYTE $0x48; BYTE $0x0f; BYTE $0xae; BYTE $0xd8;
RET
// wrgsmsr writes to the GSBASE MSR.
//
// See wrfsmsr.
TEXT ·wrgsmsr(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), AX
MOVQ AX, DX
SHRQ $32, DX
MOVQ $0xc0000101, CX // MSR_GS_BASE
BYTE $0x0f; BYTE $0x30; // WRMSR
RET
// readCR2 reads the current CR2 value.
//
// The code corresponds to:
//
// mov %cr2, %rax
//
TEXT ·readCR2(SB),NOSPLIT,$0-8
BYTE $0x0f; BYTE $0x20; BYTE $0xd0;
MOVQ AX, ret+0(FP)
RET
// fninit initializes the floating point unit.
//
// The code corresponds to:
//
// fninit
TEXT ·fninit(SB),NOSPLIT,$0
BYTE $0xdb; BYTE $0xe3;
RET
// xsetbv writes to an extended control register.
//
// The code corresponds to:
//
// xsetbv
//
TEXT ·xsetbv(SB),NOSPLIT,$0-16
MOVL reg+0(FP), CX
MOVL value+8(FP), AX
MOVL value+12(FP), DX
BYTE $0x0f; BYTE $0x01; BYTE $0xd1;
RET
// xgetbv reads an extended control register.
//
// The code corresponds to:
//
// xgetbv
//
TEXT ·xgetbv(SB),NOSPLIT,$0-16
MOVL reg+0(FP), CX
BYTE $0x0f; BYTE $0x01; BYTE $0xd0;
MOVL AX, ret+8(FP)
MOVL DX, ret+12(FP)
RET
// wrmsr writes to a control register.
//
// The code corresponds to:
//
// wrmsr
//
TEXT ·wrmsr(SB),NOSPLIT,$0-16
MOVL reg+0(FP), CX
MOVL value+8(FP), AX
MOVL value+12(FP), DX
BYTE $0x0f; BYTE $0x30;
RET
// rdmsr reads a control register.
//
// The code corresponds to:
//
// rdmsr
//
TEXT ·rdmsr(SB),NOSPLIT,$0-16
MOVL reg+0(FP), CX
BYTE $0x0f; BYTE $0x32;
MOVL AX, ret+8(FP)
MOVL DX, ret+12(FP)
RET
// stmxcsr reads the MXCSR control and status register.
TEXT ·stmxcsr(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), SI
STMXCSR (SI)
RET
// ldmxcsr writes to the MXCSR control and status register.
TEXT ·ldmxcsr(SB),NOSPLIT,$0-8
MOVQ addr+0(FP), SI
LDMXCSR (SI)
RET
|
