Minor autoconf cleanups

Make indentation and quotation consistent in configure macros.
Also remove --with-sysinclude option, which was broken for 7 years
and nobody complained.

Thanks to Ruben Kerkhof for source patches.

3 files changed, 394 insertions, 236 deletions

diff --git a/.gitignore b/.gitignore
index 52510836..0b95d3a1 100644
--- a/.gitignore
+++ b/.gitignore
@@ -5,8 +5,9 @@
 /bird
 /birdc
 /birdcl
+/bird.conf
+/bird.log
 /config.log
 /config.status
 /configure
-/bird.conf
-/bird.log
+/sysdep/autoconf.h.in
diff --git a/aclocal.m4 b/aclocal.m4
index d48846af..c4475160 100644
--- a/aclocal.m4
+++ b/aclocal.m4
@@ -2,69 +2,119 @@ dnl ** Additional Autoconf tests for BIRD configure script
 dnl ** (c) 1999 Martin Mares <mj@ucw.cz>
 
 AC_DEFUN([BIRD_CHECK_STRUCT_ALIGN],
-[AC_CACHE_CHECK([usual alignment of structures],bird_cv_c_struct_align,[
-AC_TRY_RUN([
-#include <stdio.h>
-
-struct { char x; long int y; } ary[2];
-
-int main(void)
-{
-  FILE *f = fopen("conftestresult", "w");
-  if (!f) return 10;
-  fprintf(f, "%d", sizeof(ary)/2);
-  fclose(f);
-  exit(0);
-}
-],[
-bird_cv_c_struct_align=`cat conftestresult`
-],[
-AC_MSG_RESULT([test program failed])
-AC_MSG_ERROR([Cannot determine structure alignment])
-],[bird_cv_c_struct_align=16])
-])
-AC_DEFINE_UNQUOTED([CPU_STRUCT_ALIGN], [$bird_cv_c_struct_align], [Usual alignment of structures])
+[
+  AC_CACHE_CHECK(
+    [usual alignment of structures],
+    [bird_cv_c_struct_align],
+    [
+      AC_TRY_RUN(
+	[
+	  #include <stdio.h>
+
+	  struct { char x; long int y; } ary[2];
+
+	  int main(void)
+	  {
+	    FILE *f = fopen("conftestresult", "w");
+	    if (!f)
+	      return 10;
+	    fprintf(f, "%d", sizeof(ary)/2);
+	    fclose(f);
+	    exit(0);
+	  }
+	],
+	[bird_cv_c_struct_align=$(cat conftestresult)],
+	[
+	  AC_MSG_RESULT([test program failed])
+	  AC_MSG_ERROR([Cannot determine structure alignment])
+	],
+	[bird_cv_c_struct_align=16]
+      )
+    ]
+  )
+
+  AC_DEFINE_UNQUOTED([CPU_STRUCT_ALIGN],
+    [$bird_cv_c_struct_align],
+    [Usual alignment of structures]
+  )
 ])
 
 AC_DEFUN([BIRD_CHECK_TIME_T],
-[AC_CACHE_CHECK([characteristics of time_t], bird_cv_type_time_t, [
-AC_TRY_RUN([
-#include <stdio.h>
-#include <sys/time.h>
-#include <limits.h>
-
-int main(void)
-{
-  FILE *f = fopen("conftestresult", "w");
-  if (!f) return 10;
-  fprintf(f, "%d-bit ", sizeof(time_t)*CHAR_BIT);
-  if ((time_t) -1 > 0) fprintf(f, "un");
-  fprintf(f, "signed");
-  fclose(f);
-  exit(0);
-}
-],[bird_cv_type_time_t=`cat conftestresult`
-],[	AC_MSG_RESULT([test program failed])
-	AC_MSG_ERROR([Cannot determine time_t size and signedness.])
-],[bird_cv_type_time_t="32-bit signed"])
-])
-case "$bird_cv_type_time_t" in
-	*64-bit*)	AC_DEFINE([TIME_T_IS_64BIT], [1], [Define to 1 if time_t is 64 bit]) ;;
-	esac
-case "$bird_cv_type_time_t" in
-	*unsigned*)	;;
-	*)		AC_DEFINE([TIME_T_IS_SIGNED], [1], [Define to 1 if time_t is signed]) ;;
-	esac
+[
+  AC_CACHE_CHECK(
+    [characteristics of time_t],
+    [bird_cv_type_time_t],
+    [
+      AC_TRY_RUN(
+	[
+	  #include <stdio.h>
+	  #include <sys/time.h>
+	  #include <limits.h>
+
+	  int main(void)
+	  {
+	    FILE *f = fopen("conftestresult", "w");
+	    if (!f)
+	      return 10;
+	    fprintf(f, "%d-bit ", sizeof(time_t)*CHAR_BIT);
+	    if ((time_t) -1 > 0)
+	      fprintf(f, "un");
+	    fprintf(f, "signed");
+	    fclose(f);
+	    exit(0);
+	  }
+	],
+	[bird_cv_type_time_t=$(cat conftestresult)],
+	[
+	  AC_MSG_RESULT([test program failed])
+	  AC_MSG_ERROR([Cannot determine time_t size and signedness.])
+	],
+	[bird_cv_type_time_t="32-bit signed"]
+      )
+    ]
+  )
+
+  case "$bird_cv_type_time_t" in
+    *64-bit*)
+      AC_DEFINE([TIME_T_IS_64BIT], [1],	[Define to 1 if time_t is 64 bit])
+      ;;
+  esac
+
+  case "$bird_cv_type_time_t" in
+    *unsigned*)
+      ;;
+    *)
+      AC_DEFINE([TIME_T_IS_SIGNED], [1], [Define to 1 if time_t is signed])
+      ;;
+  esac
 ])
 
 AC_DEFUN([BIRD_CHECK_PTHREADS],
 [
   bird_tmp_cflags="$CFLAGS"
-
   CFLAGS="$CFLAGS -pthread"
-  AC_CACHE_CHECK([whether POSIX threads are available], bird_cv_lib_pthreads,
-    [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[pthread_t pt; pthread_create(&pt, NULL, NULL, NULL); pthread_spinlock_t lock; pthread_spin_lock(&lock); ]])],
-		    [bird_cv_lib_pthreads=yes], [bird_cv_lib_pthreads=no])])
+
+  AC_CACHE_CHECK(
+    [whether POSIX threads are available],
+    [bird_cv_lib_pthreads],
+    [
+      AC_LINK_IFELSE(
+	[
+	  AC_LANG_PROGRAM(
+	    [ #include <pthread.h> ],
+	    [
+	      pthread_t pt;
+	      pthread_create(&pt, NULL, NULL, NULL);
+	      pthread_spinlock_t lock;
+	      pthread_spin_lock(&lock);
+	    ]
+	  )
+	],
+	[bird_cv_lib_pthreads=yes],
+	[bird_cv_lib_pthreads=no]
+      )
+    ]
+  )
 
   CFLAGS="$bird_tmp_cflags"
 ])
@@ -72,10 +122,19 @@ AC_DEFUN([BIRD_CHECK_PTHREADS],
 AC_DEFUN([BIRD_CHECK_GCC_OPTION],
 [
   bird_tmp_cflags="$CFLAGS"
-
   CFLAGS="$3 $2"
-  AC_CACHE_CHECK([whether CC supports $2], $1,
-    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], [$1=yes], [$1=no])])
+
+  AC_CACHE_CHECK(
+    [whether CC supports $2],
+    [$1],
+    [
+      AC_COMPILE_IFELSE(
+	[AC_LANG_PROGRAM()],
+	[$1=yes],
+	[$1=no]
+      )
+    ]
+  )
 
   CFLAGS="$bird_tmp_cflags"
 ])
@@ -88,14 +147,19 @@ AC_DEFUN([BIRD_ADD_GCC_OPTION],
 ])
 
 # BIRD_CHECK_PROG_FLAVOR_GNU(PROGRAM-PATH, IF-SUCCESS, [IF-FAILURE])
-# copied autoconf internal _AC_PATH_PROG_FLAVOR_GNU
+# copied from autoconf internal _AC_PATH_PROG_FLAVOR_GNU
 AC_DEFUN([BIRD_CHECK_PROG_FLAVOR_GNU],
-[# Check for GNU $1
-case `"$1" --version 2>&1` in
-*GNU*)
-  $2;;
-m4_ifval([$3],
-[*)
-  $3;;
-])esac
+[
+  # Check for GNU $1
+  case `"$1" --version 2>&1` in
+    *GNU*)
+      $2
+      ;;
+  m4_ifval([$3],
+    [*)
+      $3
+      ;;
+    ]
+  )
+  esac
 ])
diff --git a/configure.ac b/configure.ac
index ca8d7690..aac5679c 100644
--- a/configure.ac
+++ b/configure.ac
@@ -4,191 +4,258 @@ dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
 
 AC_INIT
 AC_CONFIG_SRCDIR([conf/confbase.Y])
-AC_CONFIG_AUX_DIR(tools)
-
-AC_ARG_ENABLE(debug,	[  --enable-debug          enable internal debugging routines (default: disabled)],,enable_debug=no)
-AC_ARG_ENABLE(memcheck,	[  --enable-memcheck       check memory allocations when debugging (default: enabled)],,enable_memcheck=yes)
-AC_ARG_ENABLE(client,	[  --enable-client         enable building of BIRD client (default: enabled)],,enable_client=yes)
-AC_ARG_ENABLE(ipv6,	[  --enable-ipv6           enable building of IPv6 version (default: disabled)],,enable_ipv6=no)
-AC_ARG_ENABLE(pthreads,	[  --enable-pthreads       enable POSIX threads support (default: detect)],,enable_pthreads=try)
-AC_ARG_WITH(suffix,	[  --with-suffix=STRING    use specified suffix for BIRD files (default: 6 for IPv6 version)],[given_suffix="yes"])
-AC_ARG_WITH(sysconfig,	[  --with-sysconfig=FILE   use specified BIRD system configuration file])
-AC_ARG_WITH(protocols,	[  --with-protocols=LIST   include specified routing protocols (default: all)],,[with_protocols="all"])
-AC_ARG_WITH(sysinclude,	[  --with-sysinclude=PATH  search for system includes on specified place])
-AC_ARG_WITH(runtimedir,	[  --with-runtimedir=PATH  path for runtime files (default: $(localstatedir)/run)],[runtimedir="$with_runtimedir"],[runtimedir="\$(localstatedir)/run"])
-AC_ARG_WITH(iproutedir,	[  --with-iproutedir=PATH  path to iproute2 config files (default: /etc/iproute2)],[given_iproutedir="yes"])
+AC_CONFIG_AUX_DIR([tools])
+
+AC_ARG_ENABLE([client],
+  [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
+  [],
+  [enable_client=yes]
+)
+
+AC_ARG_ENABLE([debug],
+  [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
+  [],
+  [enable_debug=no]
+)
+
+AC_ARG_ENABLE([ipv6],
+  [AS_HELP_STRING([--enable-ipv6], [enable building of IPv6 version @<:@no@:>@])],
+  [],
+  [enable_ipv6=no]
+)
+
+AC_ARG_ENABLE([memcheck],
+  [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
+  [],
+  [enable_memcheck=yes]
+)
+
+AC_ARG_ENABLE([pthreads],
+  [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
+  [],
+  [enable_pthreads=try]
+)
+
+AC_ARG_WITH([protocols],
+  [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
+  [],
+  [with_protocols="all"]
+)
+
+AC_ARG_WITH([suffix],
+  [AS_HELP_STRING([--with-suffix=STRING], [use specified suffix for BIRD files @<:@6 for IPv6@:>@])],
+  [given_suffix="yes"]
+)
+
+AC_ARG_WITH([sysconfig],
+  [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
+  []
+)
+
+AC_ARG_WITH([runtimedir],
+  [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
+  [runtimedir="$with_runtimedir"],
+  [runtimedir="\$(localstatedir)/run"]
+)
+
+AC_ARG_WITH([iproutedir],
+  [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
+  [given_iproutedir="yes"]
+)
+
 AC_ARG_VAR([FLEX], [location of the Flex program])
 AC_ARG_VAR([BISON], [location of the Bison program])
 AC_ARG_VAR([M4], [location of the M4 program])
 
 
 if test "$srcdir" = . ; then
-	# Building in current directory => create obj directory holding all objects
-	objdir=obj
-	mkdir -p obj
-	srcdir_rel=..
-	makefiles="Makefile:tools/Makefile-top.in obj/Makefile:tools/Makefile.in obj/Rules:tools/Rules.in"
-	exedir=..
+  # Building in current directory => create obj directory holding all objects
+  objdir=obj
+  mkdir -p obj
+  srcdir_rel=..
+  makefiles="Makefile:tools/Makefile-top.in obj/Makefile:tools/Makefile.in obj/Rules:tools/Rules.in"
+  exedir=..
 else
-	# Building in separate directory
-	objdir=.
-	srcdir_rel=$srcdir
-	makefiles="Makefile:tools/Makefile.in Rules:tools/Rules.in"
-	exedir=.
+  # Building in separate directory
+  objdir=.
+  srcdir_rel=$srcdir
+  makefiles="Makefile:tools/Makefile.in Rules:tools/Rules.in"
+  exedir=.
 fi
+
 case $srcdir_rel in
-	/*)	srcdir_rel_mf=$srcdir_rel ;;
-	*)	srcdir_rel_mf="\$(root-rel)$srcdir_rel" ;;
+  /*)	srcdir_rel_mf=$srcdir_rel ;;
+  *)	srcdir_rel_mf="\$(root-rel)$srcdir_rel" ;;
 esac
-AC_SUBST(objdir)
-AC_SUBST(exedir)
-AC_SUBST(srcdir_rel_mf)
-AC_SUBST(runtimedir)
+
+AC_SUBST([objdir])
+AC_SUBST([exedir])
+AC_SUBST([srcdir_rel_mf])
+AC_SUBST([runtimedir])
 
 if test "$enable_ipv6" = yes ; then
-	ip=ipv6
-	SUFFIX=6
-	proto_radv=radv
+  ip=ipv6
+  SUFFIX=6
+  proto_radv=radv
 else
-	ip=ipv4
-	SUFFIX=""
+  ip=ipv4
+  SUFFIX=""
 fi
 
 if test "$given_suffix" = yes ; then
-   	SUFFIX="$with_suffix"
+  SUFFIX="$with_suffix"
 fi
-AC_SUBST(SUFFIX)
+AC_SUBST([SUFFIX])
 
 if test "$enable_debug" = yes ; then
-	CONFIG_FILE="bird$SUFFIX.conf"
-	CONTROL_SOCKET="bird$SUFFIX.ctl"
+  CONFIG_FILE="bird$SUFFIX.conf"
+  CONTROL_SOCKET="bird$SUFFIX.ctl"
 else
-	CONFIG_FILE="\$(sysconfdir)/bird$SUFFIX.conf"
-	CONTROL_SOCKET="$runtimedir/bird$SUFFIX.ctl"
+  CONFIG_FILE="\$(sysconfdir)/bird$SUFFIX.conf"
+  CONTROL_SOCKET="$runtimedir/bird$SUFFIX.ctl"
 fi
-AC_SUBST(CONFIG_FILE)
-AC_SUBST(CONTROL_SOCKET)
+AC_SUBST([CONFIG_FILE])
+AC_SUBST([CONTROL_SOCKET])
 
-AC_SEARCH_LIBS(clock_gettime, [rt posix4], ,
-	AC_MSG_ERROR([[Function clock_gettime not available.]]))
+AC_SEARCH_LIBS([clock_gettime], [rt posix4],
+  [],
+  [AC_MSG_ERROR([Function clock_gettime not available.])]
+)
 
 AC_CANONICAL_HOST
 
 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 if test "$ac_test_CFLAGS" != set ; then
-	bird_cflags_default=yes
+  bird_cflags_default=yes
 fi
 
 AC_PROG_CC
 if test -z "$GCC" ; then
-	AC_MSG_ERROR([This program requires the GNU C Compiler.])
+  AC_MSG_ERROR([This program requires the GNU C Compiler.])
 fi
 
 if test "$enable_pthreads" != no ; then
-	BIRD_CHECK_PTHREADS
-
-	if test "$bird_cv_lib_pthreads" = yes ; then
-		AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
-		CFLAGS="$CFLAGS -pthread"
-		LDFLAGS="$LDFLAGS -pthread"
-		proto_bfd=bfd
-	elif test "$enable_pthreads" = yes ; then
-		AC_MSG_ERROR([POSIX threads not available.])
-	fi
-
-	if test "$enable_pthreads" = try ; then
-		enable_pthreads="$bird_cv_lib_pthreads"
-	fi
+  BIRD_CHECK_PTHREADS
+
+  if test "$bird_cv_lib_pthreads" = yes ; then
+    AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
+    CFLAGS="$CFLAGS -pthread"
+    LDFLAGS="$LDFLAGS -pthread"
+    proto_bfd=bfd
+  elif test "$enable_pthreads" = yes ; then
+    AC_MSG_ERROR([POSIX threads not available.])
+  fi
+
+  if test "$enable_pthreads" = try ; then
+    enable_pthreads="$bird_cv_lib_pthreads"
+  fi
 fi
 
 if test "$bird_cflags_default" = yes ; then
-	BIRD_CHECK_GCC_OPTION(bird_cv_c_option_wno_pointer_sign, -Wno-pointer-sign, -Wall)
-	BIRD_CHECK_GCC_OPTION(bird_cv_c_option_wno_missing_init, -Wno-missing-field-initializers, -Wall -Wextra)
-	BIRD_CHECK_GCC_OPTION(bird_cv_c_option_fno_strict_aliasing, -fno-strict-aliasing)
-	BIRD_CHECK_GCC_OPTION(bird_cv_c_option_fno_strict_overflow, -fno-strict-overflow)
-
-	CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
-	BIRD_ADD_GCC_OPTION(bird_cv_c_option_wno_pointer_sign, -Wno-pointer-sign)
-	BIRD_ADD_GCC_OPTION(bird_cv_c_option_wno_missing_init, -Wno-missing-field-initializers)
-	BIRD_ADD_GCC_OPTION(bird_cv_c_option_fno_strict_aliasing, -fno-strict-aliasing)
-	BIRD_ADD_GCC_OPTION(bird_cv_c_option_fno_strict_overflow, -fno-strict-overflow)
+  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
+  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
+  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
+  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
+
+  CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
+  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
+  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
+  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
+  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 fi
 AC_MSG_CHECKING([CFLAGS])
-AC_MSG_RESULT($CFLAGS)
+AC_MSG_RESULT([$CFLAGS])
 
 
 AC_PROG_CPP
 AC_PROG_INSTALL
 AC_PROG_RANLIB
-AC_CHECK_PROG(FLEX, flex, flex)
-AC_CHECK_PROG(BISON, bison, bison)
-AC_CHECK_PROGS(M4, gm4 m4)
+AC_CHECK_PROG([FLEX], [flex], [flex])
+AC_CHECK_PROG([BISON], [bison], [bison])
+AC_CHECK_PROGS([M4], [gm4 m4])
 
 test -z "$FLEX"	 && AC_MSG_ERROR([Flex is missing.])
 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 test -z "$M4"	 && AC_MSG_ERROR([M4 is missing.])
-BIRD_CHECK_PROG_FLAVOR_GNU([$M4], , [AC_MSG_ERROR([Provided M4 is not GNU M4.])])
+
+BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
+  [],
+  [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
+)
 
 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
-	if test -f $with_sysconfig ; then
-		sysdesc=$with_sysconfig
-	else
-		sysdesc=$srcdir/sysdep/cf/$with_sysconfig
-		if ! test -f $sysdesc ; then
-			sysdesc=$sysdesc.h
-		fi
-	fi
+  if test -f $with_sysconfig ; then
+    sysdesc=$with_sysconfig
+  else
+    sysdesc=$srcdir/sysdep/cf/$with_sysconfig
+    if ! test -f $sysdesc ; then
+      sysdesc=$sysdesc.h
+    fi
+  fi
 elif test -f sysconfig.h ; then
-	sysdesc=sysconfig
+  sysdesc=sysconfig
 else
-	case "$ip:$host_os" in
-		ipv6:linux*)	sysdesc=linux-v6
-				default_iproutedir="/etc/iproute2"
-				;;
-		ipv4:linux*)	sysdesc=linux
-				default_iproutedir="/etc/iproute2"
-				;;
-		ipv6:netbsd*)	sysdesc=bsd-v6
-				CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
-				LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
-				;;
-		ipv4:netbsd*)	sysdesc=bsd
-				CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
-				LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
-				;;
-		ipv6:freebsd*)	sysdesc=bsd-v6
-				;;
-		ipv4:freebsd*)	sysdesc=bsd
-				;;
-		ipv6:dragonfly*)	sysdesc=bsd-v6
-				;;
-		ipv4:dragonfly*)	sysdesc=bsd
-				;;
-		ipv6:kfreebsd*) sysdesc=bsd-v6
-				;;
-		ipv4:kfreebsd*) sysdesc=bsd
-				;;
-		ipv6:openbsd*)	sysdesc=bsd-v6
-				;;
-		ipv4:openbsd*)	sysdesc=bsd
-				;;
-		*)		AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
-				;;
-		esac
-	sysdesc=$srcdir/sysdep/cf/$sysdesc.h
+  case "$ip:$host_os" in
+    ipv6:linux*)
+      sysdesc=linux-v6
+      default_iproutedir="/etc/iproute2"
+      ;;
+    ipv4:linux*)
+      sysdesc=linux
+      default_iproutedir="/etc/iproute2"
+      ;;
+    ipv6:netbsd*)
+      sysdesc=bsd-v6
+      CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
+      LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
+      ;;
+    ipv4:netbsd*)
+      sysdesc=bsd
+      CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
+      LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
+      ;;
+    ipv6:freebsd*)
+      sysdesc=bsd-v6
+      ;;
+    ipv4:freebsd*)
+      sysdesc=bsd
+      ;;
+    ipv6:dragonfly*)
+      sysdesc=bsd-v6
+      ;;
+    ipv4:dragonfly*)
+      sysdesc=bsd
+      ;;
+    ipv6:kfreebsd*)
+      sysdesc=bsd-v6
+      ;;
+    ipv4:kfreebsd*)
+      sysdesc=bsd
+      ;;
+    ipv6:openbsd*)
+      sysdesc=bsd-v6
+      ;;
+    ipv4:openbsd*)
+      sysdesc=bsd
+      ;;
+    *)
+      AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
+      ;;
+  esac
+  sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 fi
 AC_MSG_CHECKING([which OS configuration should we use])
-AC_MSG_RESULT($sysdesc)
+AC_MSG_RESULT([$sysdesc])
 if ! test -f $sysdesc ; then
-	AC_MSG_ERROR([The system configuration file is missing.])
+  AC_MSG_ERROR([The system configuration file is missing.])
 fi
 sysname=`echo $sysdesc | sed 's/\.h$//'`
 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 
 AC_MSG_CHECKING([system-dependent directories])
 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '` lib"
-AC_MSG_RESULT($sysdep_dirs)
-AC_SUBST(sysdep_dirs)
+AC_MSG_RESULT([$sysdep_dirs])
+AC_SUBST([sysdep_dirs])
 
 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 
@@ -197,7 +264,7 @@ then iproutedir=$with_iproutedir
 else iproutedir=$default_iproutedir
 fi
 
-AC_SUBST(iproutedir)
+AC_SUBST([iproutedir])
 
 all_protocols="$proto_bfd bgp ospf pipe $proto_radv rip static"
 if test "$ip" = ipv6 ; then
@@ -206,7 +273,7 @@ fi
 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 
 if test "$with_protocols" = all ; then
-	with_protocols="$all_protocols"
+  with_protocols="$all_protocols"
 fi
 
 AH_TEMPLATE([CONFIG_BABEL], 	[Babel protocol])
@@ -222,22 +289,26 @@ AC_MSG_CHECKING([protocols])
 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 if test "$protocols" = no ; then protocols= ; fi
 for a in $protocols ; do
-	if ! test -f $srcdir/proto/$a/Makefile ; then
-		AC_MSG_RESULT(failed)
-		AC_MSG_ERROR([Requested protocol $a not found.])
-		fi
-	AC_DEFINE_UNQUOTED(CONFIG_`echo $a | tr 'a-z' 'A-Z'`)
-	done
-AC_MSG_RESULT(ok)
-AC_SUBST(protocols)
+  if ! test -f $srcdir/proto/$a/Makefile ; then
+    AC_MSG_RESULT([failed])
+    AC_MSG_ERROR([Requested protocol $a not found])
+  fi
+  AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
+done
+AC_MSG_RESULT([ok])
+AC_SUBST([protocols])
 
 case $sysdesc in
-	*/linux*|*/linux-v6*)
-		AC_CHECK_HEADER(linux/rtnetlink.h,,[AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],[
-#include <asm/types.h>
-#include <sys/socket.h>
-])
-		;;
+  */linux*|*/linux-v6*)
+    AC_CHECK_HEADER([linux/rtnetlink.h],
+      [],
+      [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
+      [
+	#include <asm/types.h>
+	#include <sys/socket.h>
+      ]
+    )
+    ;;
 esac
 
 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
@@ -253,43 +324,65 @@ BIRD_CHECK_STRUCT_ALIGN
 BIRD_CHECK_TIME_T
 
 if test "$enable_debug" = yes ; then
-	AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
-	if test "$enable_memcheck" = yes ; then
-		AC_CHECK_LIB(dmalloc, dmalloc_debug)
-		if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
-			AC_CHECK_LIB(efence, malloc)
-		fi
-	fi
+  AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
+  if test "$enable_memcheck" = yes ; then
+    AC_CHECK_LIB([dmalloc], [dmalloc_debug])
+    if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
+      AC_CHECK_LIB([efence], [malloc])
+    fi
+  fi
 fi
 
 CLIENT=
 CLIENT_LIBS=
 if test "$enable_client" = yes ; then
-	CLIENT=birdc
-	AC_CHECK_LIB(history, add_history, CLIENT_LIBS="-lhistory")
-	AC_CHECK_LIB(ncurses, tgetent, USE_TERMCAP_LIB=-lncurses,
-		AC_CHECK_LIB(curses, tgetent, USE_TERMCAP_LIB=-lcurses,
-			AC_CHECK_LIB(tinfow, tgetent, USE_TERMCAP_LIB=-ltinfow,
-				AC_CHECK_LIB(tinfo, tgetent, USE_TERMCAP_LIB=-ltinfo,
-					AC_CHECK_LIB(termcap, tgetent, USE_TERMCAP_LIB=-ltermcap,
-						AC_MSG_ERROR([[The client requires ncurses library. Either install the library or use --disable-client to compile without the client.]]))))))
-	AC_CHECK_LIB(readline, rl_callback_read_char, CLIENT_LIBS="-lreadline $CLIENT_LIBS $USE_TERMCAP_LIB",
-		AC_MSG_ERROR([[The client requires GNU readline library 2.1 or newer. Either install the library or use --disable-client to compile without the client.]]), $USE_TERMCAP_LIB)
-	AC_CHECK_LIB(readline, rl_crlf, AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()]),,$USE_TERMCAP_LIB)
-	AC_CHECK_LIB(readline, rl_ding, AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()]),,$USE_TERMCAP_LIB)
+  CLIENT=birdc
+  AC_CHECK_LIB([history], [add_history], [CLIENT_LIBS="-lhistory"])
+  AC_CHECK_LIB([ncurses], [tgetent], [USE_TERMCAP_LIB=-lncurses],
+    AC_CHECK_LIB([curses], [tgetent], [USE_TERMCAP_LIB=-lcurses],
+      AC_CHECK_LIB([tinfow], [tgetent], [USE_TERMCAP_LIB=-ltinfow],
+	AC_CHECK_LIB([tinfo], [tgetent], [USE_TERMCAP_LIB=-ltinfo],
+	  AC_CHECK_LIB([termcap], [tgetent], [USE_TERMCAP_LIB=-ltermcap],
+	    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])]
+	  )
+	)
+      )
+    )
+  )
+
+  AC_CHECK_LIB([readline], [rl_callback_read_char],
+    [CLIENT_LIBS="-lreadline $CLIENT_LIBS $USE_TERMCAP_LIB"],
+    [AC_MSG_ERROR([The client requires GNU readline library 2.1 or newer. Either install the library or use --disable-client to compile without the client.])],
+    [$USE_TERMCAP_LIB]
+  )
+
+  AC_CHECK_LIB([readline], [rl_crlf],
+    [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
+    [],
+    [$USE_TERMCAP_LIB]
+  )
+
+  AC_CHECK_LIB([readline], [rl_ding],
+    [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
+    [],
+    [$USE_TERMCAP_LIB]
+  )
 fi
-AC_SUBST(CLIENT)
-AC_SUBST(CLIENT_LIBS)
+AC_SUBST([CLIENT])
+AC_SUBST([CLIENT_LIBS])
 
 mkdir -p $objdir/sysdep
 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
-AC_CONFIG_COMMANDS([merge],[[export CPP="$CPP"
-$srcdir/tools/mergedirs $srcdir $srcdir_rel $objdir $sysdep_dirs]],
-	[[srcdir=$srcdir]
-	[srcdir_rel=$srcdir_rel]
-	[objdir=$objdir]
-	[sysdep_dirs="$sysdep_dirs"]])
-AC_CONFIG_FILES($makefiles)
+AC_CONFIG_COMMANDS([merge],
+  [ export CPP="$CPP"; $srcdir/tools/mergedirs $srcdir $srcdir_rel $objdir $sysdep_dirs ],
+  [
+    srcdir=$srcdir
+    srcdir_rel=$srcdir_rel
+    objdir=$objdir
+    sysdep_dirs="$sysdep_dirs"
+  ]
+)
+AC_CONFIG_FILES([$makefiles])
 AC_OUTPUT
 
 rm -f $objdir/sysdep/paths.h